****************************************************************
* PROGRAM:      PCD.SAS                                 	   *
* PROGRAMMER:   Jennifer Godwin							       *
* DATE:         12/28/06                                       *
*                                                              *
* PURPOSE:      Create scored SAS dataset                      *
*                                                              *
* INPUT:        pXag               							   *
* OUTPUT:       PCDX										   *
****************************************************************;


** Name library holding SAS input data files **;

LIBNAME SASIN  "I:\datacenter\SASDATA\Datasets\Parent\Parentreportdelinquency\U" ;
LIBNAME SASOUT  "I:\datacenter\SASDATA\Datasets\Parent\Parentreportdelinquency\S" ;


** Enter year of data collection **;

  %let yr  = 13; 

*************** DO NOT MODIFY BELOW THIS LINE ******************************;

%macro linmean;
data &INDATA;
   set &INDATA;
   label &var_name = "&var_labl";
   array sumvars {*} &var_list;
   if n(of sumvars(*))>=.5*dim(sumvars) then &var_name=mean(of sumvars(*));
 proc sort; by site tcid;
 run;
%mend linmean;

data PCD;
set sasin.p&yr.ag;


array one (*) p&yr.ag6-p&yr.ag17;

array two (*) p&yr.ag6r p&yr.ag7r p&yr.ag8r p&yr.ag9r p&yr.ag10r p&yr.ag11r 
				p&yr.ag12r p&yr.ag13r p&yr.ag14r p&yr.ag15r p&yr.ag16r p&yr.ag17r;

do i=1 to dim(one);
	two(i) =one(i)-1;
	end;
	run;

%let indata=PCD;

			%let var_name = PCD&yr.SUB ;
	        %let var_labl = %str(Substance Abuse - PCD Y&yr.) ;
	        %let var_list = %str(p&yr.ag6r p&yr.ag7r p&yr.ag8r p&yr.ag9r ) ;
	        %linmean ;

			%let var_name = PCD&yr.TFT ;
	        %let var_labl = %str(Theft - PCD Y&yr.) ;
	        %let var_list = %str(p&yr.ag10r p&yr.ag12r ) ;
	        %linmean;

			%let var_name = PCD&yr.INT ;
	        %let var_labl = %str(Interpersonal violence - PCD Y&yr.) ;
	        %let var_list = %str(p&yr.ag11r p&yr.ag16r) ;
	        %linmean;

			%let var_name = PCD&yr.STS ;
	        %let var_labl = %str(Status Offenses - PCD Y&yr.) ;
	        %let var_list = %str(p&yr.ag13r p&yr.ag14r  p&yr.ag15r) ;
	        %linmean;

			%let var_name = PCD&yr.GEN;
	        %let var_labl = %str(General Delinquency - PCD Y&yr.) ;
	        %let var_list = %str(p&yr.ag6r p&yr.ag7r p&yr.ag8r p&yr.ag9r 
								p&yr.ag10r p&yr.ag11r p&yr.ag12r p&yr.ag13r p&yr.ag14r  
								p&yr.ag15r p&yr.ag16r  p&yr.ag17r ) ;
	        %linmean;

data sasout.PCD&yr.;
set PCD;
LABEL
P&yr.AG6r="Recoded-How often has your child-Drank alcohol beyond a few sips?"
P&yr.AG7r="Recoded-How often has your child-Been drunk in a public place?"
P&yr.AG8r="Recoded-How often has your child-Used illegal drugs such as heroin, crack, cocaine, or LSD?"
P&yr.AG9r="Recoded-How often has your child-Sold illegal drugs?"
P&yr.AG10r="Recoded-How often has your child-Stolen or tried to steal something worth more than $50?"
P&yr.AG11r="Recoded-How often has your child-Attacked someone with a weapon with the idea of seriously hurting them?"
P&yr.AG12r="Recoded-How often has your child-Taken some money at home that did not belong to them without asking?"
P&yr.AG13r="Recoded-How often has your child-Been suspended or expelled for bad behavior at school?"
P&yr.AG14r="Recoded-How often has your child-Been in trouble with the police for something he or she did?"
P&yr.AG15r="Recoded-How often has your child-Run away from home?"
P&yr.AG16r="Recoded-How often has your child-Carried a weapon?"
P&yr.AG17r="Recoded-How often has your child-Purposely set fire to a house, car, or building?";
drop i;

run;

proc sort;by cohort site tcid;
run;