***********************************************************************
* PROGRAM:      rct.sas                                               *
* PROGRAMMER:   Bobby Laird                                           *
* DATE:         08/20/97                                              *
*                                                                     *
* PURPOSE:      Conflict Tactics Scale scoring program.               *
*																	  *
* Modified:		Feb 2004 Jennifer Godwin to run on aggregate data	  *
*																	  *
* Modified:		March 2004 Cindy Rains for revised shortened conflict *
*				tactics scale										  *																  *
* INPUT:        CxAR 												  *
*																	  *
* OUTPUT:       RCTx							                      *
*                                                                     *
***********************************************************************;

** Fill out information below for data processed in this run **;

** Name library holding SAS input data files **;

  LIBNAME SASIN 'l:\cohort 1\grade 11\child interview' ;

** Specify library for output datasets **;

  LIBNAME SASOUT 'J:\cindy rains' ;

** Allkey file**;

  LIBNAME K 'l:\' ;

** Enter year of data collection **;

 %let yr =12; 


*****************************************************************************;
DATA RCT;
SET SASIN.dc&yr.ar1 SASIN.nc&yr.ar1 SASIN.pc&yr.ar1 SASIN.sc&yr.ar1 ;

**Need to convert .P to 0 to b/c nothing actually happened in past year.  
Then use new variables below to capture data about previous violence. Per Ken Dodge 3/25/04**;
**Also, create new lifetime scores to see if violence occurred in the past or present, per Pat malone, 4/30/04**;
array orig (30) c&yr.ar8-c&yr.ar37;
array recode (30) c&yr.ar8r c&yr.ar9r c&yr.ar10r c&yr.ar11r c&yr.ar12r c&yr.ar13r c&yr.ar14r c&yr.ar15r c&yr.ar16r
				 c&yr.ar17r c&yr.ar18r c&yr.ar19r c&yr.ar20r c&yr.ar21r c&yr.ar22r c&yr.ar23r c&yr.ar24r c&yr.ar25r
				 c&yr.ar26r c&yr.ar27r c&yr.ar28r c&yr.ar29r c&yr.ar30r c&yr.ar31r c&yr.ar32r c&yr.ar33r c&yr.ar34r
				 c&yr.ar35r c&yr.ar36r c&yr.ar37r;
array past (30) c&yr.arp8-c&yr.arp37;
array lifetime (30) c&yr.arx8-c&yr.arx37;

do i=1 to 30;
if orig(i)=.P then recode(i)=0;
else recode(i)=orig(i);
end;

do j=1 to 30;
if orig(j)=.P then past(j)=1; 
else if orig(j) in (.,.s,.n) then past(j)=.;
else if orig(j) in (0,1,2,3,4,5,6) then past(j)=0;
end;

do j=1 to 30;
if orig(j)=0 then lifetime(j)=0; 
else if orig(j) in (.,.s,.n) then lifetime(j)=.;
else if orig(j) in (.P,1,2,3,4,5,6) then lifetime(j)=1;
end;

Label

c&yr.arx8= "In my lifetime, I have shown my boyfriend/girlfriend I cared even though I disagreed w/him/her"
c&yr.arx9= "In my lifetime, my boyfriend/girlfriend has shown he/she cared for me even though we disagreed"
c&yr.arx10= "In my lifetime, I have insulted or swore at my boyfriend/girlfriend"
c&yr.arx11= "In my lifetime, my boyfriend/girlfriend has insulted or swore at me"
c&yr.arx12= "In my lifetime, I have thrown something at my boyfriend/girlfriend"
c&yr.arx13= "In my lifetime, my boyfriend/girlfriend has thrown something at me"
c&yr.arx14= "In my lifetime, I have twisted my boyfriend/girlfriend's arm or hair"
c&yr.arx15= "In my lifetime, my boyfriend/girlfriend has twisted my arm or hair"
c&yr.arx16= "In my lifetime, I have shown respect for my boyfriend/girlfriend's feelings"
c&yr.arx17= "In my lifetime, my boyfriend/girlfriend has shown respect for my feelings"
c&yr.arx18= "In my lifetime, I have pushed/shoved my boyfriend/girlfriend"
c&yr.arx19= "In my lifetime, my boyfriend/girlfriend has pushed/shoved me"
c&yr.arx20= "In my lifetime, I have punched/hit my boyfriend/girlfriend w/something that could hurt"
c&yr.arx21= "In my lifetime, my boyfriend/girlfriend has punched/hit me w/something that could hurt"
c&yr.arx22= "In my lifetime, I have destroyed something belonging to my boyfriend/girlfriend"
c&yr.arx23= "In my lifetime, my boyfriend/girlfriend has destroyed something belonging to me"
c&yr.arx24= "In my lifetime, I have shouted/yelled at my boyfriend/girlfriend"
c&yr.arx25= "In my lifetime, my boyfriend/girlfriend has shouted/yelled at me"
c&yr.arx26= "In my lifetime, I said I was sure we could work out a problem"
c&yr.arx27= "In my lifetime, my boyfriend/girlfriend was sure we could work out a problem"
c&yr.arx28= "In my lifetime, I have grabbed my boyfriend/girlfriend"
c&yr.arx29= "In my lifetime, my boyfriend/girlfriend has grabbed me"
c&yr.arx30= "In my lifetime, I have slapped my boyfriend/girlfriend"
c&yr.arx31= "In my lifetime, my boyfriend/girlfriend has slapped me"
c&yr.arx32= "In my lifetime, I have suggested a compromise to a disagreement"
c&yr.arx33= "In my lifetime, my boyfriend/girlfriend has suggested a compromise to a disagreement"
c&yr.arx34= "In my lifetime, I have threatened to hit/throw something at my boyfriend/girlfriend"
c&yr.arx35= "In my lifetime, my boyfriend/girlfriend has threatened to hit/throw something at me"
c&yr.arx36= "In my lifetime, I have kicked my boyfriend/girlfriend"
c&yr.arx37= "In my lifetime, my boyfriend/girlfriend has kicked me"
c&yr.arp8= "In the past, I showed my boyfriend/girlfriend I cared even though I disagreed w/him/her"
c&yr.arp9= "In the past, my boyfriend/girlfriend showed he/she cared for me even though we disagreed"
c&yr.arp10= "In the past, I insulted or swore at my boyfriend/girlfriend"
c&yr.arp11= "In the past, my boyfriend/girlfriend insulted or swore at me"
c&yr.arp12= "In the past, I threw something at my boyfriend/girlfriend"
c&yr.arp13= "In the past, my boyfriend/girlfriend threw something at me"
c&yr.arp14= "In the past, I twisted my boyfriend/girlfriend's arm or hair"
c&yr.arp15= "In the past, my boyfriend/girlfriend twisted my arm or hair"
c&yr.arp16= "In the past, I showed respect for my boyfriend/girlfriend's feelings"
c&yr.arp17= "In the past, my boyfriend/girlfriend showed respect for my feelings"
c&yr.arp18= "In the past, I pushed/shoved my boyfriend/girlfriend"
c&yr.arp19= "In the past, my boyfriend/girlfriend pushed/shoved me"
c&yr.arp20= "In the past, I punched/hit my boyfriend/girlfriend w/something that could hurt"
c&yr.arp21= "In the past, my boyfriend/girlfriend punched/hit me w/something that could hurt"
c&yr.arp22= "In the past, I destroyed something belonging to my boyfriend/girlfriend"
c&yr.arp23= "In the past, my boyfriend/girlfriend destroyed something belonging to me"
c&yr.arp24= "In the past, I shouted/yelled at my boyfriend/girlfriend"
c&yr.arp25= "In the past, my boyfriend/girlfriend shouted/yelled at me"
c&yr.arp26= "In the past, I said I was sure we could work out a problem"
c&yr.arp27= "In the past, my boyfriend/girlfriend was sure we could work out a problem"
c&yr.arp28= "In the past, I grabbed my boyfriend/girlfriend"
c&yr.arp29= "In the past, my boyfriend/girlfriend grabbed me"
c&yr.arp30= "In the past, I slapped my boyfriend/girlfriend"
c&yr.arp31= "In the past, my boyfriend/girlfriend slapped me"
c&yr.arp32= "In the past, I suggested a compromise to a disagreement"
c&yr.arp33= "In the past, my boyfriend/girlfriend suggested a compromise to a disagreement"
c&yr.arp34= "In the past, I threatened to hit/throw something at my boyfriend/girlfriend"
c&yr.arp35= "In the past, my boyfriend/girlfriend threatened to hit/throw something at me"
c&yr.arp36= "In the past, I kicked my boyfriend/girlfriend"
c&yr.arp37= "In the past, my boyfriend/girlfriend kicked me"
c&yr.ar8r="Recoded-I showed my boyfriend/girlfriend I cared even though I disagreed w/him/her"
c&yr.ar9r= "Recoded-my boyfriend/girlfriend showed he/she cared for me even though we disagreed"
c&yr.ar10r="Recoded-I insulted or swore at my boyfriend/girlfriend"
c&yr.ar11r="Recoded-my boyfriend/girlfriend insulted or swore at me"
c&yr.ar12r="Recoded-I threw something at my boyfriend/girlfriend"
c&yr.ar13r="Recoded-my boyfriend/girlfriend threw something at me"
c&yr.ar14r="Recoded-I twisted my boyfriend/girlfriend's arm or hair"
c&yr.ar15r="Recoded-my boyfriend/girlfriend twisted my arm or hair"
c&yr.ar16r="Recoded-I showed respect for my boyfriend/girlfriend's feelings"
c&yr.ar17r="Recoded-my boyfriend/girlfriend showed respect for my feelings"
c&yr.ar18r="Recoded-I pushed/shoved my boyfriend/girlfriend"
c&yr.ar19r="Recoded-my boyfriend/girlfriend pushed/shoved me"
c&yr.ar20r="Recoded-I punched/hit my boyfriend/girlfriend w/something that could hurt"
c&yr.ar21r="Recoded-my boyfriend/girlfriend punched/hit me w/something that could hurt"
c&yr.ar22r="Recoded-I destroyed something belonging to my boyfriend/girlfriend"
c&yr.ar23r="Recoded-my boyfriend/girlfriend destroyed something belonging to me"
c&yr.ar24r="Recoded-I shouted/yelled at my boyfriend/girlfriend"
c&yr.ar25r="Recoded-my boyfriend/girlfriend shouted/yelled at me"
c&yr.ar26r="Recoded-I said I was sure we could work out a problem"
c&yr.ar27r="Recoded-my boyfriend/girlfriend was sure we could work out a problem"
c&yr.ar28r="Recoded-I grabbed my boyfriend/girlfriend"
c&yr.ar29r="Recoded-my boyfriend/girlfriend grabbed me"
c&yr.ar30r="Recoded-I slapped my boyfriend/girlfriend"
c&yr.ar31r="Recoded-my boyfriend/girlfriend slapped me"
c&yr.ar32r="Recoded-I suggested a compromise to a disagreement"
c&yr.ar33r="Recoded-my boyfriend/girlfriend suggested a compromise to a disagreement"
c&yr.ar34r="Recoded-I threatened to hit/throw something at my boyfriend/girlfriend"
c&yr.ar35r="Recoded-my boyfriend/girlfriend threatened to hit/throw something at me"
c&yr.ar36r="Recoded-I kicked my boyfriend/girlfriend"
c&yr.ar37r="Recoded-my boyfriend/girlfriend kicked me"
;
run;


*when calculating the mean;
%macro linmean;
data &INDATA;
   set &INDATA;
   label &var_name = "&var_labl";
   array sumvars {*} &var_list;
   if n(of sumvars(*))>=.5*dim(sumvars) then &var_name=mean(of sumvars(*));
 proc sort; by site tcid;
 run;
%mend linmean;

/* Specify definitions for SCALE VARIABLES below:         ** */;
        %let INDATA = RCT ;

/* Student to Partner */;

************************************************************;
%let var_name = RCT&yr.PA1 ;
%let var_labl = %str(Physical Aggr. - Student) ;
%let var_list = %str(c&yr.ar12r c&yr.ar14r c&yr.ar18r c&yr.ar20r c&yr.ar22r c&yr.ar28r c&yr.ar30r c&yr.ar36r) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.VA1;
%let var_labl = %str(Verbal Aggr. - Student) ;
%let var_list = %str(c&yr.ar10r c&yr.ar24r c&yr.ar34r ) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.DS1 ;
%let var_labl = %str(Verbal Discuss. - Student) ;
%let var_list = %str(c&yr.ar8r c&yr.ar16r c&yr.ar26r c&yr.ar32r) ;
%linmean ;
************************************************************;
************************************************************;
%let var_name = RCT&yr.PP1 ;
%let var_labl = %str(Previous Physical Aggr. - Student) ;
%let var_list = %str(c&yr.arp12 c&yr.arp14 c&yr.arp18 c&yr.arp20 c&yr.arp22 c&yr.arp28 c&yr.arp30 c&yr.arp36) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.PV1;
%let var_labl = %str(Previous Verbal Aggr. - Student) ;
%let var_list = %str(c&yr.arp10 c&yr.arp24 c&yr.arp34 ) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.PD1 ;
%let var_labl = %str(Previous Verbal Discuss. - Student) ;
%let var_list = %str(c&yr.arp8 c&yr.arp16 c&yr.arp26 c&yr.arp32) ;
%linmean ;
************************************************************;
************************************************************;
%let var_name = RCT&yr.LP1 ;
%let var_labl = %str(Lifetime Physical Aggr. - Student) ;
%let var_list = %str(c&yr.arx12 c&yr.arx14 c&yr.arx18 c&yr.arx20 c&yr.arx22 c&yr.arx28 c&yr.arx30 c&yr.arx36) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.LV1;
%let var_labl = %str(Lifetime Verbal Aggr. - Student) ;
%let var_list = %str(c&yr.arx10 c&yr.arx24 c&yr.arx34 ) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.LD1 ;
%let var_labl = %str(Lifetime Verbal Discuss. - Student) ;
%let var_list = %str(c&yr.arx8 c&yr.arx16 c&yr.arx26 c&yr.arx32) ;
%linmean ;
************************************************************;

/* Partner to Student */;

************************************************************;
%let var_name = RCT&yr.PA2 ;
%let var_labl = %str(Physical Aggr. - Partner) ;
%let var_list = %str(c&yr.ar13r c&yr.ar15r c&yr.ar19r c&yr.ar21r c&yr.ar23r c&yr.ar29r c&yr.ar31r c&yr.ar37r) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.VA2;
%let var_labl = %str(Verbal Aggr. - Partner) ;
%let var_list = %str(c&yr.ar11r c&yr.ar25r c&yr.ar35r ) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.DS2 ;
%let var_labl = %str(Verbal Discuss. - Partner) ;
%let var_list = %str(c&yr.ar9r c&yr.ar17r c&yr.ar27r c&yr.ar33r) ;
%linmean ;
************************************************************;
************************************************************;
%let var_name = RCT&yr.PP2 ;
%let var_labl = %str(Previous Physical Aggr. - Partner) ;
%let var_list = %str(c&yr.arp13 c&yr.arp15 c&yr.arp19 c&yr.arp21 c&yr.arp23 c&yr.arp29 c&yr.arp31 c&yr.arp37) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.PV2;
%let var_labl = %str(Previous Verbal Aggr. - Partner) ;
%let var_list = %str(c&yr.arp11 c&yr.arp25 c&yr.arp35 ) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.PD2 ;
%let var_labl = %str(Previous Verbal Discuss. - Partner) ;
%let var_list = %str(c&yr.arp9 c&yr.arp17 c&yr.arp27 c&yr.arp33) ;
%linmean ;
************************************************************;
************************************************************;
%let var_name = RCT&yr.LP2 ;
%let var_labl = %str(Lifetime Physical Aggr. - Partner) ;
%let var_list = %str(c&yr.arx13 c&yr.arx15 c&yr.arx19 c&yr.arx21 c&yr.arx23 c&yr.arx29 c&yr.arx31 c&yr.arx37) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.LV2;
%let var_labl = %str(Lifetime Verbal Aggr. - Partner) ;
%let var_list = %str(c&yr.arx11 c&yr.arx25 c&yr.arx35 ) ;
%linmean ;
************************************************************;
%let var_name = RCT&yr.LD2 ;
%let var_labl = %str(Lifetime Verbal Discuss. - Partner) ;
%let var_list = %str(c&yr.arx9 c&yr.arx17 c&yr.arx27 c&yr.arx33) ;
%linmean ;
************************************************************;

DATA sasout.RCT&yr;
set RCT ;
DROP i j;
run;


/*proc means;run;*/

proc contents; run;